Selamat datang di blog ali-mahdali.blogstpot.com, kali ini penulis memposting artikel yang berjudul MIKROTIK INTERAKTIF BOT TELEGRAM DINAMIS TANPA SERVER yang mana artikel ini dapat kalian akses melalui alamat : https://ali-mahdali.blogspot.com/2026/01/interaktif-bot-telegram-dinamis-tanpa.html,
tanpa basa-basi yuk disimak artikelnya dibawah ini. Selamat membaca
berikut ini schedule untuk interaktif open bot telegram secara dinamis
:global botToken
:local timeout 5
:global lastUpdateId
:local url ("https://api.telegram.org/bot" . $botToken . "/getUpdates?timeout=" . $timeout . "&limit=1&offset=" . ($lastUpdateId + 1))
:local res [/tool fetch url=$url as-value output=user]
:local data ($res->"data")
:local updStart [:find $data "\"update_id\":"]
:local updateid ""
:if ($updStart != nil) do={
:local afterUpd ($updStart + 12)
:local updEnd [:find $data "," $afterUpd]
:if ($updEnd != nil) do={
:set updateid [:pick $data $afterUpd $updEnd]
:set updateid [:tonum $updateid]
}
}
:local text ""
:local textStart [:find $data "\"text\":\""]
:if ($textStart != nil) do={
:local textEnd [:find $data "\"" ($textStart + 8)]
:if ($textEnd != nil) do={
:set text [:pick $data ($textStart + 8) $textEnd]
}
}
:if ($updateid != "" && $updateid > $lastUpdateId) do={
# Update lastUpdateId
:set lastUpdateId $updateid
:local chatid2 ""
:local chatStart [:find $data "\"chat\":{\"id\":"]
:if ($chatStart != nil) do={
:local afterChat ($chatStart + 13)
:local chatEnd [:find $data "," $afterChat]
:if ($chatEnd != nil) do={
:set chatid2 [:pick $data $afterChat $chatEnd]
}
}
# ---------------------------------------BALASAN----------------------------------------------
:local identity [/system identity get name]
:local header ("\F0\9F\93\A1 " . $identity . "%0A---------------------------%0A")
:local footer ("%0A---------------------------%0A\F0\9F\93\9C MENU:%0A/start | /cpu | /offline | /uptime")
:local reply ""
:if ($text = "/start") do={
:set reply ("Selamat Datang di Bot MikroTik%0ASilakan gunakan menu di bawah untuk monitoring.")
} else={
:if ($text = "/cpu") do={
:local cpuLoad [/system resource get cpu-load]
:set reply ("\F0\9F\93\8A INFO CPU%0ACPU Load: " . $cpuLoad . "%")
} else={
:if ($text = "/offline") do={
:local list ""
:local jumlahoffline 0
:local activeUsers ","
:foreach a in=[/ppp active find] do={
:set activeUsers ($activeUsers . [/ppp active get $a name] . ",")
}
:foreach i in=[/ppp secret find] do={
:local n [/ppp secret get $i name]
:if (!($activeUsers ~ ("," . $n . ","))) do={
:set jumlahoffline ($jumlahoffline + 1)
:set list ($list . "%0A" . $jumlahoffline . ". \F0\9F\94\A5 " . $n)
}
}
:if ($jumlahoffline > 0) do={
:set reply ($jumlahoffline . " USER OFFLINE \E2\9B\94 :" . $list)
} else={
:set reply "\E2\9C\85 SEMUA USER ONLINE"
}
} else={
:if ($text = "/uptime") do={
:local up [/system resource get uptime]
:set reply ("\F0\9F\97\93 INFO UPTIME%0AUptime: " . $up)
} else={
:set reply "\E2\9A\A0 Perintah tidak dikenal."
}
}
}
}
:local pesanFinal ($header . $reply . $footer)
:local sendUrl ("https://api.telegram.org/bot" . $botToken . "/sendMessage")
:local postData ("chat_id=" . $chatid2 . "&text=" . $pesanFinal)
/tool fetch url=$sendUrl http-method=post http-data=$postData output=none
#---------------------------------------BALASAN----------------------------------------------
}
Terimakasih atas kunjungan Anda dan Karena telah sudi membaca artikel yang berjudul MIKROTIK INTERAKTIF BOT TELEGRAM DINAMIS TANPA SERVER.Tak Lengkap Rasanya Jika Kunjungan Anda di Blog ini Tanpa Meninggalkan Komentar, untuk Itu Silahkan Berikan Kritik dan saran Pada Kotak Komentar di bawah. Anda boleh menyebarluaskan atau mengcopy artikel MIKROTIK INTERAKTIF BOT TELEGRAM DINAMIS TANPA SERVER ini jika memang bermanfaat bagi anda, namun jangan lupa untuk mencantumkan link sumbernya. Terima Kasih, Happy Blogging :)
EmoticonEmoticon